ArcFM Desktop Configuration Guide
Cost Estimate Default Style Sheet

Resource Center Home

Designer Express provides a default style sheet for the Cost Estimate report that can be exported from the Design Estimate tool. This default style sheet, Estimate.xsl, is installed automatically the first time you export a report from the Design Estimate tool. Estimate.xsl resides in one of the following locations, depending on your OS.

 

The style sheet Estimate.xsl will not be in this directory until you export a report through the Design Estimate tool.

 

Configuration in the Process Framework Administration Tool

If you want to use the default style sheet, no further configuration is necessary. The Cost Estimate report is automatically exported using the default style sheet. However, if you want to use a different style sheet, you will need to add  the ExpressEstimateStyleSheet value to the Configuration tab in Process Framework Administration Tool. The value for ExpressEstimateStyleSheet is the path to your custom style sheet.

Sample Stylesheet for the Exported Cost Estimate Report

 Below is the default style sheet for the Cost Estimate report.

DxE_Materials.xsl
Copy Code 
<?xml version='1.0'?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="html"/>
  <xsl:template match="Estimate">
    <html>
      <style>
        body {
        color: black;
        background-color: #FFFFFF;
        font-family: 'Frutiger Roman', 'Verdana', 'Arial', 'Helvetica', sans-serif;
        font-size: small;
        text-align: left;
        }
        h1, h2 {
        font-family: 'Frutiger Roman','Verdana','Arial','Helvetica',sans-serif;
        font-size: medium;
        font-style: normal;
        font-weight: bold;
        color: rgb(253, 71, 3);
        }
        .DesignTd {
        border: 0px;
        font-family: 'Frutiger Roman','Verdana','Arial','Helvetica',sans-serif;
        }
        thead{
        background-color:highlight; color:highlighttext; border:1px white solid;
        }
        hr {
        background-color: #545454;
        }
        .highlight{
        background-color: #3DC1FF; color: black;
        }
        .title {
        text-decoration: none;
        font-style: italic;
        }
        .footer, a {
        text-align: left;
        font-size: 10px;
        color: #545454;
        }
        img {
        font-family: 'Frutiger Roman','Verdana','Arial','Helvetica',sans-serif;
        font-size: large;
        font-style: normal;
        font-weight: bold;
        color: rgb(253, 71, 3);
        }
        .total{
        font-weight: bold;
        }
      </style>
      <body>
        <img src="Logo.jpg" alt="Schneider Electric" />
        <br />
        <hr />
        <p align="center">
          <h1>Designer Express: Cost Estimate</h1>
        </p>
        <p align="left">
          <h3>
            <xsl:apply-templates select="ExpressDesign"/>
          </h3>
        </p>
        <hr />
        <table style="font-size:small; BORDER: black 1px solid; background-color:#eeeecc; table-layout:fixed"
               borderColor="#999999" cellSpacing="0" cellPadding="2" border="1"  slcolor="#ffffcc" hlcolor="#BEC5DE">
          <tr>
            <th style="width:12pc">Code</th>
            <th>Description</th>
            <th style="width:7pc">Category</th>
            <th style="width:7pc">Quantity</th>
            <th style="width:7pc">Unit Price</th>
            <th style="width:7pc">Price</th>
          </tr>
          <xsl:for-each select="CostItem">
            <tr>
              <td align="center">
                <xsl:value-of select="@code"/>
                &#160;
              </td>
              <td align="center">
                <xsl:value-of select="Description"/>
                &#160;
              </td>
              <td align="center">
                <xsl:value-of select="Category"/>
                &#160;
              </td>
              <td align="center">
                <xsl:value-of select="Quantity"/>
                &#160;
              </td>
              <td align="center">
                <xsl:value-of select="UnitPrice"/>
                &#160;
              </td>
              <td align="center">
                <xsl:value-of select="Price"/>
                &#160;
              </td>
            </tr>
          </xsl:for-each>
          <tr>
            <td align="center">
            </td>
            <td align="center">
            </td>
            <td align="center">
            </td>
            <td align="center">
            </td>
            <td align="center">
              Total:
            </td>
            <td align="center">
              <xsl:value-of select="Total"/>
            </td>
          </tr>
        </table>
        <div class="footer">
          <hr />
          Copyright &#xA9; 2010-2014 <a href="http://www.schneider-electric.com" target="_blank">Schneider Electric, Inc.</a>
        </div>
      </body>
    </html>
  </xsl:template>
  <xsl:template match="ExpressDesign">
    <div align="left">
      <table  style="text-align: left" border="0" cellpadding="5" cellspacing="0">
        <tr style="vertical-align: top; text-align: left">
          <td class="DesignTd">
            Work Request Name:
          </td>
          <td class="DesignTd">
            <xsl:value-of select="@WorkRequestName"/>
          </td>
        </tr>
        <tr class="DesignTr">
          <td class="DesignTd">
            Design Name:
          </td>
          <td class="DesignTd">
            <xsl:value-of select="@DesignName"/>
            <br />
          </td>
        </tr>
        <tr style="vertical-align: top; text-align: left">
          <td class="DesignTd">
            Designer Name:
          </td>
          <td class="DesignTd">
            <xsl:value-of select="@DesignerName"/>
          </td>
        </tr>
        <tr style="vertical-align: top; text-align: left">
          <td class="DesignTd" width="250">
            Work Request Address:
          </td>
          <td class="DesignTd">
            <xsl:apply-templates select="Address"/>
          </td>
        </tr>
      </table>
    </div>
  </xsl:template>
  <xsl:template match="Address">
    <xsl:if test="Address1!=''">
      <xsl:value-of select="Address1"/>
      <br/>
    </xsl:if>
    <xsl:if test="Address2!=''">
      <xsl:value-of select="Address2"/>
      <br/>
    </xsl:if>
    <xsl:choose>
      <xsl:when test="City!=''">
        <xsl:value-of select="City"/><xsl:if test="State!=''">
          , <xsl:value-of select="State"/>
        </xsl:if>&#160;<xsl:value-of select="Zip"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="State"/>&#160;<xsl:value-of select="Zip"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
  <xsl:template match="Address2">
    <xsl:if test="Address1[.='']">
      none
    </xsl:if>
    <xsl:if test="Address1[.!='']">
      <xsl:value-of select="Address1"/> <br />
      <xsl:if test="Address2[.!='']">
        <xsl:value-of select="Address2"/> <br />
      </xsl:if>
      <xsl:value-of select="City"/>,
      <xsl:value-of select="State"/>&#160;<xsl:value-of select="Zip"/>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

 

 

 

Send Comment to ArcFMdocumentation@schneider-electric.com